@echo off
title AviSynth64 Installer v3
IF %PROCESSOR_ARCHITECTURE% == x86 (GOTO 32BIT)
REG QUERY "HKLM\SOFTWARE\Wow6432Node\AviSynth" /ve >nul
if errorlevel 1 goto NOAVS
timeout /T 1 /NOBREAK >nul
bcdedit  >nul
IF ERRORLEVEL 1 GOTO NOADMIN
FOR /F "TOKENS=3* DELIMS= " %%A IN ('REG QUERY "HKLM\SOFTWARE\Wow6432Node\AviSynth" /v plugindir2_5') DO (SET AVSPATH=%%A %%B)
copy "%~dp0avisynth.dll" "%SYSTEMROOT%\System32" /Y >nul
copy "%~dp0DevIL.dll" "%SYSTEMROOT%\System32" /Y >nul
dir "%AVSPATH%64"
if errorlevel 1 md "%AVSPATH%64"
CLS
copy "%~dp0DirectShowSource.dll" "%AVSPATH%64\DirectshowSource.dll" /Y >nul
copy "%~dp0MT.dll" "%AVSPATH%64\MT.dll" /Y >nul
REG ADD HKLM\SOFTWARE\AviSynth /t REG_SZ /d "%AVSPATH%" /f >nul
REG ADD HKLM\SOFTWARE\AviSynth /t REG_SZ /v plugindir2_5 /d "%AVSPATH%64" /f >nul
REG ADD HKLM\SOFTWARE\Classes\AVIFile\Extensions\avs /t REG_SZ /d {E6D6B700-124D-11D4-86F3-DB80AFD98778} /f >nul
REG ADD HKLM\SOFTWARE\Classes\CLSID\{E6D6B700-124D-11D4-86F3-DB80AFD98778} /t REG_SZ /d AviSynth /f >nul
REG ADD HKLM\SOFTWARE\Classes\CLSID\{E6D6B700-124D-11D4-86F3-DB80AFD98778}\InProcServer32 /t REG_SZ /d avisynth.dll /f >nul
REG ADD HKLM\SOFTWARE\Classes\CLSID\{E6D6B700-124D-11D4-86F3-DB80AFD98778}\InProcServer32 /v ThreadingModel /t REG_SZ /d Apartment /f >nul
echo AviSynth64 installed. To auto load put 64 bit dll's in
echo %AVSPATH%64
echo. 
pause
exit

:32BIT
CLS
echo 64-bit windows not detected
pause
exit

:NOAVS
CLS
echo 32-bit AviSynth needs to be installed first
pause
exit

:NOADMIN
CLS
echo Administrator privileges required
pause
exit